namespace eval excel:: {
    variable workbooks 0
    variable workbooksArray
    variable workSheets
    variable workSheetsArray
    variable styles
    variable columnDefault
    variable data
    variable rowCounter
}
proc excel::createWorkbook {} {
#
# @comment  create a workbook pointer
# @result 	pointer to created workbook
#
    incr excel::workbooks
    set workbookName workbook$excel::workbooks
    set excel::workbooksArray($workbookName) 1
    return $workbookName
}
proc excel::createWorkSheet {workbook name} {
#
# @comment  create a worksheet pointer
# @argument workbook pointer to a workbook
# @argument name name of the worksheet
# @result 	pointer to a worksheet
#
    variable data
    if {[info exists excel::workbooksArray($workbook)]} {
        if {![info exists ::excel::workSheets($workbook)]} {
            set excel::workSheets($workbook) 1
        } else {
            incr excel::workSheets($workbook)
        }
        set workSheetName workSheet[string range ${workbook} 8 end].$excel::workSheets($workbook)
        set data(workSheet,$::excel::workSheets($workbook),name) $name
        set data(workSheet,$::excel::workSheets($workbook)) $workSheetName
        set data(workSheet,$workSheetName) 1
        set excel::rowCounter($workSheetName) 0
        return $workSheetName
    } else {
        error "$workbook is not a valid workbook"
    }
}
proc excel::createStyle {workbook args} {
#
# @comment  create an excel style
# @argument workbook pointer to a workbook
# @argument args argument list
# @result style pointer
#
    variable data
    if {[info exists excel::styles($workbook)]} {
        incr excel::styles($workbook)
    } else {
        set excel::styles($workbook) 2
    }
    set styleName s$excel::styles($workbook)
    if {[llength $args]==1} {set args [lindex $args 0]}
    foreach {name value} $args {
        # check that name is valid
        if {[lsearch "-font -fontfamily -fontcolor -fontsize -background -bold -custom -center" $name]==-1} {
            error "style option $name option is not supported"
        }
        set data($workbook,styles,$styleName,$name) $value
    }
    return $styleName

}
proc excel::setColumnType {workSheet columnIndex type} {
#
# @comment define a column type
# @argument workSheet pointer to a workSheet
# @argument columnIndex index of column
# @argument type of column
# @result  column type is changed
#
    variable data
    _checkSpreadSheet $workSheet
    set data($workSheet,row,$columnIndex,type) [string totitle $type]
}
proc excel::_checkSpreadSheet {workSheet} {
    variable data
    if {![info exists data(workSheet,$workSheet)]} {
        error "$workSheet is not a valid workSheet"
    }
}
proc excel::addRow {workSheet args} {
#
# @comment add row to excel worksheet
# @argument workSheet pointer to a workSheet
# @argument args list of variables
# @result row id
#
    variable data
    set i 0
    incr excel::rowCounter($workSheet)
    set data($workSheet,$excel::rowCounter($workSheet),length) [llength $args]
    foreach arg $args {
        incr i
        if {[llength $arg]>1} {
            if {[llength $arg]>2} {
                set data($workSheet,$excel::rowCounter($workSheet),$i,style) [lindex $arg 2]
            }
            set data($workSheet,$excel::rowCounter($workSheet),$i,type) [lindex $arg 1]
        }
        set data($workSheet,$excel::rowCounter($workSheet),$i,data) [lindex $arg 0]
    }
    return row$excel::rowCounter($workSheet)
}
proc excel::asXml {workbook} {
#
# @comment returns excel workbook as xml
# @argument workbook pointer to a workbook
# @result workbook xml representation
#
    variable data
    variable rowCounter
    set xml "<?xml version='1.0'?>
<?mso-application progid='Excel.Sheet'?>
<Workbook xmlns='urn:schemas-microsoft-com:office:spreadsheet'\
xmlns:o='urn:schemas-microsoft-com:office:office'\
xmlns:x='urn:schemas-microsoft-com:office:excel'\
xmlns:ss='urn:schemas-microsoft-com:office:spreadsheet'\
xmlns:html='http://www.w3.org/TR/REC-html40'>\
<DocumentProperties xmlns='urn:schemas-microsoft-com:office:office'>
<Created>[clock format [clock seconds] -format {%Y-%m-%dT%H:%M:%SZ}]</Created>
</DocumentProperties>
<Styles>
<Style ss:ID='Default' ss:Name='Normal'>
<Alignment ss:Vertical='Bottom'/>
<Font ss:FontName='Calibri' x:Family='Swiss' ss:Size='8' ss:Color='#000000'/>
</Style>
<Style ss:ID='s1'>
<Alignment ss:Vertical='Bottom'/>
<Font ss:FontName='Calibri' x:Family='Swiss' ss:Size='8' ss:Color='#000000'/>
</Style>\n"
    if {[info exists excel::styles($workbook)]} {
        for {set d 2} {$d<=$excel::styles($workbook)} {incr d} {
            set styleName s$d
            if {[info exists data($workbook,styles,$styleName,-center)]} {
                append xml "<Style ss:ID='$styleName'>\n<Alignment ss:Horizontal='Center' ss:Vertical='Bottom'/>\n"
            } else {append xml "<Style ss:ID='$styleName'>\n<Alignment ss:Vertical='Bottom'/>\n"}
            if {[info exists data($workbook,styles,$styleName,-font)] || [info exists data($workbook,styles,$styleName,-fontfamily)] ||\
                [info exists data($workbook,styles,$styleName,-fontsize)] || [info exists data($workbook,styles,$styleName,-fontcolor)] ||\
                [info exists data($workbook,styles,$styleName,-bold)]} {
                append xml "<Font"
                if {[info exists data($workbook,styles,$styleName,-font)]} {
                    append xml " ss:FontName='$data($workbook,styles,$styleName,-font)'"
                }
                if {[info exists data($workbook,styles,$styleName,-fontfamily)]} {
                    append xml " x:Family='$data($workbook,styles,$styleName,-fontfamily)'"
                }
                if {[info exists data($workbook,styles,$styleName,-fontsize)]} {
                    append xml " ss:Size='$data($workbook,styles,$styleName,-fontsize)'"
                }
                if {[info exists data($workbook,styles,$styleName,-fontcolor)]} {
                    append xml " ss:Color='$data($workbook,styles,$styleName,-fontcolor)'"
                }
                if {[info exists data($workbook,styles,$styleName,-bold)]} {
                    append xml " ss:Bold='1'"
                }
                append xml "/>\n"
            }
            if {[info exists data($workbook,styles,$styleName,-background)]} {
                append xml "<Interior ss:Color='$data($workbook,styles,$styleName,-background)' ss:Pattern='Solid'/>\n"
            }
            if {[info exists data($workbook,styles,$styleName,-custom)]} {
                append xml $data($workbook,styles,$styleName,-custom)
            }
            append xml "</Style>\n"
        }
    }
    append xml "</Styles>\n"
    for {set d 1} {$d<=$excel::workSheets($workbook)} {incr d} {
        append xml "<Worksheet ss:Name='$excel::data(workSheet,$d,name)'>\n"
        append xml "<Table x:FullColumns='1' x:FullRows='1' ss:DefaultColumnWidth='71.25'>\n"
        set workSheet $excel::data(workSheet,$d)
        for {set i 1} {$i<=$excel::rowCounter($workSheet)} {incr i} {
            append xml "<Row>\n"
            for {set j 1} {$j<=$data($workSheet,$i,length)} {incr j} {
                if {[info exists data($workSheet,$i,$j,type)]} {
                    set type $data($workSheet,$i,$j,type)
                } else {
                    if {[info exists data($workSheet,row,$j,type)]} {
                        set type $data($workSheet,row,$j,type)
                    } else {
                        set type "Number"
                    }
                }
                set dataValue $data($workSheet,$i,$j,data)
                append xml "<Cell"
                if {[info exists data($workSheet,$i,$j,style)]} {
                    append xml " ss:StyleID='$data($workSheet,$i,$j,style)'"
                }
                if {[string index $dataValue 0]=="="} {
                    append xml " ss:Formula='$dataValue'"
                    set dataValue ""
                }
                append xml ">"
                append xml "<Data ss:Type='$type'>$dataValue</Data></Cell>\n"
            }
            append xml "</Row>\n"
        }
        append xml "</Table>\n"
        append xml "<WorksheetOptions xmlns='urn:schemas-microsoft-com:office:excel'>
<PageSetup>
<Layout x:Orientation='Landscape'/>
<Header x:Margin='0'/>
<Footer x:Margin='0'/>
<PageMargins x:Bottom='0' x:Left='0' x:Right='0' x:Top='0'/>
</PageSetup>
<Print>
<ValidPrinterInfo/>
<HorizontalResolution>600</HorizontalResolution>
<VerticalResolution>600</VerticalResolution>
</Print>
<Selected/>
<ProtectObjects>False</ProtectObjects>
<ProtectScenarios>False</ProtectScenarios>
</WorksheetOptions>\n"
        append xml "</Worksheet>\n"
    }
    append xml "</Workbook>\n"
}
proc excel::deleteWorkbook {workbook} {
#
# @comment  delete a workbook pointer
# @argument workbook pointer to a workbook
# @result undecoded string
#
    variable data
    for {set d 1} {$d<=$excel::workSheets($workbook)} {incr d} {
        array unset data $d
            set workSheet $excel::data(workSheet,$d)
        for {set i 1} {$i<=$excel::rowCounter($workSheet)} {incr i} {
            array unset data $workSheet*
        }
        array unset excel::rowCounter $workSheet
    }
}
package provide excel 1.0